Update

Kha/Tools/macos_x64/std/jvm/_std/haxe/Rest.hx

@@ -0,0 +1,61 @@
+package haxe;
+
+import haxe.ds.Vector;
+import haxe.iterators.RestIterator;
+import haxe.iterators.RestKeyValueIterator;
+
+private typedef NativeRest<T> = Vector<T>;
+
+@:coreApi
+abstract Rest<T>(NativeRest<T>) {
+	public var length(get, never):Int;
+
+	inline function get_length():Int
+		return this.length;
+
+	inline function new(a:NativeRest<T>) {
+		this = a;
+	}
+
+	@:arrayAccess inline function get(index:Int):T
+		return this[index];
+
+	@:from extern inline static public function of<T>(array:Array<T>):Rest<T> {
+		var result = new NativeRest(array.length);
+		for (i in 0...array.length)
+			result[i] = array[i];
+		return new Rest(result);
+	}
+
+	@:from extern inline static function fromNative<T>(a:java.NativeArray<T>):Rest<T> {
+		return new Rest(Vector.fromData(a));
+	}
+
+	extern inline public function append(item:T):Rest<T> {
+		var r = new NativeRest(length + 1);
+		Vector.blit(this, 0, r, 0, length);
+		r[length] = item;
+		return new Rest(r);
+	}
+
+	extern inline public function prepend(item:T):Rest<T> {
+		var r = new NativeRest(length + 1);
+		Vector.blit(this, 0, r, 1, length);
+		r[0] = item;
+		return new Rest(r);
+	}
+
+	public inline function iterator():RestIterator<T>
+		return new RestIterator<T>(this);
+
+	public inline function keyValueIterator():RestKeyValueIterator<T>
+		return new RestKeyValueIterator<T>(this);
+
+	@:to public inline function toArray():Array<T> {
+		return [for (i in 0...this.length) this[i]];
+	}
+
+	public inline function toString():String {
+		return toArray().toString();
+	}
+}

Kha/Tools/macos_x64/std/jvm/_std/haxe/ds/StringMap.hx

@@ -0,0 +1,91 @@
+/*
+ * Copyright (C)2005-2019 Haxe Foundation
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a
+ * copy of this software and associated documentation files (the "Software"),
+ * to deal in the Software without restriction, including without limitation
+ * the rights to use, copy, modify, merge, publish, distribute, sublicense,
+ * and/or sell copies of the Software, and to permit persons to whom the
+ * Software is furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+ * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+ * DEALINGS IN THE SOFTWARE.
+ */
+
+package haxe.ds;
+
+@:coreApi
+class StringMap<T> implements haxe.Constraints.IMap<String, T> {
+	var hashMap:java.util.HashMap<String, T>;
+
+	@:overload
+	public function new():Void {
+		hashMap = new java.util.HashMap();
+	}
+
+	@:overload
+	function new(hashMap:java.util.HashMap<String, T>):Void {
+		this.hashMap = hashMap;
+	}
+
+	public function set(key:String, value:T):Void {
+		hashMap.put(key, value);
+	}
+
+	public function get(key:String):Null<T> {
+		return hashMap.get(key);
+	}
+
+	public function exists(key:String):Bool {
+		return hashMap.containsKey(key);
+	}
+
+	public function remove(key:String):Bool {
+		var has = exists(key);
+		hashMap.remove(key);
+		return has;
+	}
+
+	public inline function keys():Iterator<String> {
+		return hashMap.keySet().iterator();
+	}
+
+	@:runtime public inline function keyValueIterator():KeyValueIterator<String, T> {
+		return new haxe.iterators.MapKeyValueIterator(this);
+	}
+
+	public inline function iterator():Iterator<T> {
+		return hashMap.values().iterator();
+	}
+
+	public function copy():StringMap<T> {
+		return new StringMap(hashMap.clone());
+	}
+
+	public function toString():String {
+		var s = new StringBuf();
+		s.add("[");
+		var it = keys();
+		for (i in it) {
+			s.add(i);
+			s.add(" => ");
+			s.add(Std.string(get(i)));
+			if (it.hasNext())
+				s.add(", ");
+		}
+		s.add("]");
+		return s.toString();
+	}
+
+	public function clear():Void {
+		hashMap.clear();
+	}
+}