253 lines
8.3 KiB
GLSL
253 lines
8.3 KiB
GLSL
#version 450
|
|
|
|
#include "compiled.inc"
|
|
#include "std/gbuffer.glsl"
|
|
#include "std/math.glsl"
|
|
|
|
uniform sampler2D gbufferD;
|
|
uniform sampler2D tex;
|
|
uniform sampler2D sbase;
|
|
uniform sampler2D sdetail;
|
|
uniform sampler2D sfoam;
|
|
|
|
#ifdef _SSR
|
|
uniform mat4 P;
|
|
uniform mat3 V3;
|
|
#ifdef _CPostprocess
|
|
uniform vec3 PPComp9;
|
|
uniform vec3 PPComp10;
|
|
#endif
|
|
#endif
|
|
|
|
#ifdef _Rad
|
|
uniform sampler2D senvmapRadiance;
|
|
#endif
|
|
|
|
uniform float time;
|
|
uniform vec3 eye;
|
|
uniform vec3 eyeLook;
|
|
uniform vec2 cameraProj;
|
|
uniform vec3 ld;
|
|
uniform float envmapStrength;
|
|
|
|
in vec2 texCoord;
|
|
in vec3 viewRay;
|
|
out vec4 fragColor;
|
|
|
|
#ifdef _SSR
|
|
vec3 hitCoord;
|
|
float depth;
|
|
|
|
const int numBinarySearchSteps = 7;
|
|
const int maxSteps = int(ceil(1.0 / ssrRayStep) * ssrSearchDist);
|
|
|
|
vec2 getProjectedCoord(const vec3 hit) {
|
|
vec4 projectedCoord = P * vec4(hit, 1.0);
|
|
projectedCoord.xy /= projectedCoord.w;
|
|
projectedCoord.xy = projectedCoord.xy * 0.5 + 0.5;
|
|
#ifdef _InvY
|
|
projectedCoord.y = 1.0 - projectedCoord.y;
|
|
#endif
|
|
return projectedCoord.xy;
|
|
}
|
|
|
|
float getDeltaDepth(const vec3 hit) {
|
|
depth = textureLod(gbufferD, getProjectedCoord(hit), 0.0).r * 2.0 - 1.0;
|
|
vec3 viewPos = getPosView(viewRay, depth, cameraProj);
|
|
return viewPos.z - hit.z;
|
|
}
|
|
|
|
vec4 binarySearch(vec3 dir) {
|
|
float ddepth;
|
|
for (int i = 0; i < numBinarySearchSteps; i++) {
|
|
dir *= 0.5;
|
|
hitCoord -= dir;
|
|
ddepth = getDeltaDepth(hitCoord);
|
|
if (ddepth < 0.0) hitCoord += dir;
|
|
}
|
|
// Ugly discard of hits too far away
|
|
#ifdef _CPostprocess
|
|
if (abs(ddepth) > PPComp9.z / 500) return vec4(0.0);
|
|
#else
|
|
if (abs(ddepth) > ssrSearchDist / 500) return vec4(0.0);
|
|
#endif
|
|
return vec4(getProjectedCoord(hitCoord), 0.0, 1.0);
|
|
}
|
|
|
|
vec4 rayCast(vec3 dir) {
|
|
#ifdef _CPostprocess
|
|
dir *= PPComp9.x;
|
|
#else
|
|
dir *= ssrRayStep;
|
|
#endif
|
|
for (int i = 0; i < maxSteps; i++) {
|
|
hitCoord += dir;
|
|
if (getDeltaDepth(hitCoord) > 0.0) return binarySearch(dir);
|
|
}
|
|
return vec4(0.0);
|
|
}
|
|
#endif //SSR
|
|
|
|
vec3 sampleWaterNormals(vec2 hitXY, float speed, out vec2 tcnor0, out vec2 tcnor1) {
|
|
tcnor0 = hitXY / 3.0;
|
|
vec3 n0 = textureLod(sdetail, tcnor0 + vec2(speed / 60.0, speed / 120.0), 0.0).rgb;
|
|
tcnor1 = hitXY / 6.0 + n0.xy / 20.0;
|
|
vec3 n1 = textureLod(sbase, tcnor1 + vec2(speed / 40.0, speed / 80.0), 0.0).rgb;
|
|
return normalize(n0 + n1 - 1.0);
|
|
}
|
|
|
|
void main() {
|
|
float gdepth = textureLod(gbufferD, texCoord, 0.0).r * 2.0 - 1.0;
|
|
vec3 vray = normalize(viewRay);
|
|
float speed = time * 2.0 * waterSpeed;
|
|
bool isSky = (gdepth == 1.0);
|
|
|
|
// Ray-plane intersection with water surface (z = waterLevel)
|
|
float denom = dot(vray, vec3(0.0, 0.0, 1.0));
|
|
float tWater = (waterLevel - eye.z) / denom;
|
|
bool hasWaterHit = (abs(denom) > 0.0001) && (tWater > 0.0);
|
|
|
|
if (eye.z < waterLevel) {
|
|
vec2 tc = texCoord;
|
|
float fogFactor;
|
|
|
|
if (hasWaterHit && denom > 0.0) {
|
|
// Looking up at water surface - apply normal distortion
|
|
vec3 hit = eye + tWater * vray;
|
|
vec2 tc0, tc1;
|
|
vec3 n2 = sampleWaterNormals(hit.xy * waterFreq, speed, tc0, tc1);
|
|
tc = texCoord + (n2.xy * n2.z) / 30.0 * waterRefract;
|
|
fogFactor = clamp(tWater * waterDensity, 0.0, 0.95);
|
|
} else {
|
|
// Looking forward/down - distort via water surface above fragment
|
|
vec3 p = getPos(eye, eyeLook, vray, gdepth, cameraProj);
|
|
vec2 wxy = isSky ? (eye.xy + vray.xy * 50.0) : p.xy;
|
|
vec2 tc0, tc1;
|
|
vec3 n2 = sampleWaterNormals(wxy * waterFreq, speed, tc0, tc1);
|
|
tc = texCoord + (n2.xy * n2.z) / 30.0 * waterRefract;
|
|
float waterDist = isSky ? 50.0 : length(p - eye);
|
|
fogFactor = clamp(waterDist * waterDensity, 0.0, 0.95);
|
|
}
|
|
|
|
vec3 refracted = textureLod(tex, tc, 0.0).rgb;
|
|
fragColor.rgb = mix(refracted, waterColor, fogFactor);
|
|
fragColor.a = 1.0;
|
|
return;
|
|
}
|
|
|
|
// Above water
|
|
if (!hasWaterHit || denom >= 0.0) {
|
|
fragColor = vec4(0.0);
|
|
return;
|
|
}
|
|
|
|
if (isSky) tWater = min(tWater, 100.0); // Clamp to prevent aliasing at horizon
|
|
vec3 p = isSky ? (eye + tWater * vray) : getPos(eye, eyeLook, vray, gdepth, cameraProj);
|
|
|
|
float horizonFactor = clamp(1.0 - tWater / 60.0, 0.0, 1.0);
|
|
if (!isSky && p.z > waterLevel) {
|
|
fragColor = vec4(0.0);
|
|
return;
|
|
}
|
|
|
|
// Displace surface
|
|
p.z += (sin(p.x * 10.0 / waterDisplace + speed) * cos(p.y * 10.0 / waterDisplace + speed)
|
|
+ sin(p.x * 20.0 / waterDisplace + speed * 1.3) * cos(p.y * 20.0 / waterDisplace + speed * 1.3) * 0.5)
|
|
/ 50.0 * waterDisplace;
|
|
|
|
// Hit plane to determine uvs
|
|
vec3 v = normalize(eye - p);
|
|
float t = (waterLevel - eye.z) / dot(v, vec3(0.0, 0.0, 1.0));
|
|
vec3 hit = eye + t * v;
|
|
|
|
// Sample normal maps
|
|
vec2 tcnor0, tcnor1;
|
|
vec3 n2 = sampleWaterNormals(hit.xy * waterFreq, speed, tcnor0, tcnor1);
|
|
|
|
// Refraction
|
|
vec2 tc;
|
|
if (isSky) {
|
|
tc = texCoord + (n2.xy * n2.z) / 30.0 * waterRefract;
|
|
} else {
|
|
float ddepth = textureLod(gbufferD, texCoord + (n2.xy * n2.z) / 40.0, 0.0).r * 2.0 - 1.0;
|
|
vec3 p2 = getPos(eye, eyeLook, vray, ddepth, cameraProj);
|
|
tc = p2.z > waterLevel ? texCoord : texCoord + (n2.xy * n2.z) / 30.0 * waterRefract;
|
|
}
|
|
|
|
// Light
|
|
float fresnel = 1.0 - max(dot(n2, v), 0.0);
|
|
fresnel = 0.02 + 0.98 * pow(fresnel, 5.0);
|
|
vec3 r = reflect(-v, n2);
|
|
#ifdef _Rad
|
|
vec3 reflectedEnv = textureLod(senvmapRadiance, envMapEquirect(r), 0).rgb;
|
|
#else
|
|
const vec3 reflectedEnv = vec3(0.5);
|
|
#endif
|
|
vec3 refracted = textureLod(tex, tc, 0.0).rgb;
|
|
|
|
#ifdef _SSR
|
|
float roughness = 0.1;//unpackFloat(g0.b).y;
|
|
//if (roughness == 1.0) { fragColor.rgb = vec3(0.0); return; }
|
|
|
|
float spec = 0.9;//fract(textureLod(gbuffer1, texCoord, 0.0).a);
|
|
//if (spec == 0.0) { fragColor.rgb = vec3(0.0); return; }
|
|
|
|
vec3 viewNormal = V3 * n2;
|
|
vec3 viewPos = isSky ? vec3(0.0) : getPosView(viewRay, gdepth, cameraProj);
|
|
vec3 reflected = reflect(normalize(viewPos), viewNormal);
|
|
hitCoord = viewPos;
|
|
|
|
#ifdef _CPostprocess
|
|
vec3 dir = reflected * (1.0 - rand(texCoord) * PPComp10.y * roughness) * 2.0;
|
|
#else
|
|
vec3 dir = reflected * (1.0 - rand(texCoord) * ssrJitter * roughness) * 2.0;
|
|
#endif
|
|
|
|
vec4 coords = rayCast(dir);
|
|
|
|
vec2 deltaCoords = abs(vec2(0.5, 0.5) - coords.xy);
|
|
float screenEdgeFactor = clamp(1.0 - (deltaCoords.x + deltaCoords.y), 0.0, 1.0);
|
|
|
|
float reflectivity = 1.0 - roughness;
|
|
#ifdef _CPostprocess
|
|
float intensity = pow(reflectivity, PPComp10.x) * screenEdgeFactor * clamp(-reflected.z, 0.0, 1.0) * clamp((PPComp9.z - length(viewPos - hitCoord)) * (1.0 / PPComp9.z), 0.0, 1.0) * coords.w;
|
|
#else
|
|
float intensity = pow(reflectivity, ssrFalloffExp)*screenEdgeFactor*clamp(-reflected.z, 0.0, 1.0)*clamp((ssrSearchDist - length(viewPos - hitCoord))*(1.0 / ssrSearchDist), 0.0, 1.0)*coords.w;
|
|
#endif
|
|
intensity = clamp(intensity, 0.0, 1.0);
|
|
vec3 reflCol = textureLod(tex, coords.xy, 0.0).rgb;
|
|
fragColor.rgb = mix(refracted, reflCol * intensity * 0.5, waterReflect * fresnel * 0.5);
|
|
fragColor.rgb = mix(fragColor.rgb, reflectedEnv, waterReflect * fresnel);
|
|
#else
|
|
fragColor.rgb = mix(refracted, reflectedEnv, waterReflect * fresnel);
|
|
#endif
|
|
// Water color tint - blend rather than multiply to preserve brightness
|
|
float colorMix = isSky ? 0.7 : 0.5;
|
|
fragColor.rgb = mix(fragColor.rgb, fragColor.rgb * waterColor, colorMix * horizonFactor);
|
|
// Blinn-Phong specular using half-vector, faded at horizon
|
|
vec3 h = normalize(v + ld);
|
|
float specAmount = pow(max(dot(n2, h), 0.0), 200.0) * (200.0 + 8.0) / (PI * 8.0);
|
|
fragColor.rgb += specAmount * (isSky ? 0.3 : 1.0) * horizonFactor;
|
|
// Depth fog - blend toward waterColor with depth, faded at horizon
|
|
float depthFog = clamp(-(p.z - waterLevel) * waterDensity, 0.0, 0.9);
|
|
fragColor.rgb = mix(fragColor.rgb, waterColor, depthFog * horizonFactor);
|
|
// Alpha fades smoothly at horizon instead of hard cut
|
|
fragColor.a = isSky ? horizonFactor : clamp(abs(p.z - waterLevel) * 5.0, 0.0, 1.0);
|
|
|
|
// Foam - based on actual geometry depth below water surface
|
|
float fd = isSky ? 1.0 : abs(p.z - waterLevel);
|
|
if (fd < 0.1) {
|
|
// Based on foam by Owen Deery
|
|
// http://fire-face.com/personal/water
|
|
// Distance-based LOD blurs foam at range to reduce noise
|
|
float foamLod = clamp(tWater / 15.0, 0.0, 5.0);
|
|
vec2 foamUV0 = tcnor0 * 3.0 + vec2(speed / 30.0, speed / 50.0);
|
|
vec2 foamUV1 = tcnor1 * 4.0 + vec2(-speed / 35.0, speed / 45.0);
|
|
vec3 foamMask0 = textureLod(sfoam, foamUV0, foamLod).rgb;
|
|
vec3 foamMask1 = textureLod(sfoam, foamUV1, foamLod).rgb;
|
|
float foamStrength = clamp(1.0 - foamMask0.r * 0.5 - foamMask1.b * 0.5, 0.0, 1.0);
|
|
float fac = (1.0 - (fd * (1.0 / 0.1))) * horizonFactor;
|
|
fragColor.rgb = mix(fragColor.rgb, mix(fragColor.rgb, waterColor + 0.2, foamStrength), clamp(fac, 0.0, 1.0) * 0.5);
|
|
}
|
|
}
|