forked from LeenkxTeam/LNXSDK
510 lines
13 KiB
GLSL
510 lines
13 KiB
GLSL
#version 450
|
|
|
|
#include "compiled.inc"
|
|
#include "std/gbuffer.glsl"
|
|
#include "std/math.glsl"
|
|
#include "std/brdf.glsl"
|
|
#ifdef _Clusters
|
|
#include "std/clusters.glsl"
|
|
#endif
|
|
#ifdef _Irr
|
|
#include "std/shirr.glsl"
|
|
#endif
|
|
|
|
uniform sampler2D gbufferD;
|
|
uniform sampler2D gbuffer0;
|
|
uniform sampler2D gbuffer1;
|
|
#ifdef _gbuffer2
|
|
uniform sampler2D gbuffer2;
|
|
#endif
|
|
#ifdef _ClearCoat
|
|
uniform sampler2D gbufferCoatNormal;
|
|
#endif
|
|
|
|
uniform float envmapStrength;
|
|
#ifdef _Irr
|
|
uniform vec4 shirr[7];
|
|
#endif
|
|
#ifdef _Brdf
|
|
uniform sampler2D senvmapBrdf;
|
|
#endif
|
|
#ifdef _Rad
|
|
uniform sampler2D senvmapRadiance;
|
|
uniform int envmapNumMipmaps;
|
|
#endif
|
|
#ifdef _EnvCol
|
|
uniform vec3 backgroundCol;
|
|
#endif
|
|
|
|
#ifdef _SMSizeUniform
|
|
//!uniform vec2 smSizeUniform;
|
|
#endif
|
|
uniform vec2 cameraProj;
|
|
uniform vec3 eye;
|
|
uniform vec3 eyeLook;
|
|
|
|
#ifdef _Clusters
|
|
uniform vec4 lightsArray[maxLights * 3];
|
|
#ifdef _Spot
|
|
uniform vec4 lightsArraySpot[maxLights * 2];
|
|
#endif
|
|
uniform sampler2D clustersData;
|
|
uniform vec2 cameraPlane;
|
|
#endif
|
|
|
|
#ifdef _ShadowMap
|
|
#ifdef _SinglePoint
|
|
#ifdef _Spot
|
|
//!uniform sampler2DShadow shadowMapSpot[1];
|
|
//!uniform mat4 LWVPSpotArray[1];
|
|
#else
|
|
//!uniform samplerCubeShadow shadowMapPoint[1];
|
|
//!uniform vec2 lightProj;
|
|
#endif
|
|
#endif
|
|
#ifdef _Clusters
|
|
#ifdef _ShadowMapAtlas
|
|
#ifdef _SingleAtlas
|
|
uniform sampler2DShadow shadowMapAtlas;
|
|
#endif
|
|
#endif
|
|
#ifdef _ShadowMapAtlas
|
|
#ifndef _SingleAtlas
|
|
//!uniform sampler2DShadow shadowMapAtlasPoint;
|
|
#endif
|
|
//!uniform vec4 pointLightDataArray[4];
|
|
#else
|
|
//!uniform samplerCubeShadow shadowMapPoint[4];
|
|
#endif
|
|
//!uniform vec2 lightProj;
|
|
#ifdef _Spot
|
|
#ifdef _ShadowMapAtlas
|
|
#ifndef _SingleAtlas
|
|
//!uniform sampler2DShadow shadowMapAtlasSpot;
|
|
#endif
|
|
#else
|
|
//!uniform sampler2DShadow shadowMapSpot[4];
|
|
#endif
|
|
//!uniform mat4 LWVPSpotArray[4];
|
|
#endif
|
|
#endif
|
|
#endif
|
|
|
|
#ifdef _Sun
|
|
uniform vec3 sunDir;
|
|
uniform vec3 sunCol;
|
|
#ifdef _ShadowMap
|
|
#ifdef _ShadowMapAtlas
|
|
#ifndef _SingleAtlas
|
|
uniform sampler2DShadow shadowMapAtlasSun;
|
|
#endif
|
|
//!uniform vec4 tileBoundsSunArray[maxLights * shadowmapCascades];
|
|
#else
|
|
uniform sampler2DShadow shadowMap;
|
|
#endif
|
|
uniform float shadowsBias;
|
|
#ifdef _CSM
|
|
//!uniform vec4 casData[shadowmapCascades * 4 + 4];
|
|
#else
|
|
uniform mat4 LWVP;
|
|
#endif
|
|
#endif // _ShadowMap
|
|
#endif
|
|
|
|
#ifdef _SinglePoint // Fast path for single light
|
|
uniform vec3 pointPos;
|
|
uniform vec3 pointCol;
|
|
uniform float pointBias;
|
|
#ifdef _Spot
|
|
uniform vec3 spotDir;
|
|
uniform vec3 spotRight;
|
|
uniform vec4 spotData;
|
|
#endif
|
|
#endif
|
|
|
|
#include "std/light_mobile.glsl"
|
|
|
|
in vec2 texCoord;
|
|
in vec3 viewRay;
|
|
out vec4 fragColor;
|
|
|
|
void main() {
|
|
vec4 g0 = textureLod(gbuffer0, texCoord, 0.0); // Normal.xy, roughness, metallic/matid
|
|
|
|
vec3 n;
|
|
n.z = 1.0 - abs(g0.x) - abs(g0.y);
|
|
n.xy = n.z >= 0.0 ? g0.xy : octahedronWrap(g0.xy);
|
|
n = normalize(n);
|
|
|
|
float roughness = g0.b;
|
|
float metallic;
|
|
uint matid;
|
|
unpackFloatInt16(g0.a, metallic, matid);
|
|
#ifdef _ExtBRDF
|
|
matid = min(matid, uint(MAX_MATERIALS - 1));
|
|
|
|
//!uniform vec4 materialParams[MAX_MATERIALS * 8];
|
|
vec4 matp0 = vec4(0.0), matp1 = vec4(0.0), matp2 = vec4(0.0), matp3 = vec4(0.0);
|
|
vec4 matp4 = vec4(0.0), matp5 = vec4(0.0), matp6 = vec4(0.0), matp7 = vec4(0.0);
|
|
// TODO: coatIOR=1.5, ior=1.45, thinWall=1.0 move to python make files
|
|
matp1.z = 1.5;
|
|
matp3.x = 1.45;
|
|
matp3.y = 1.0;
|
|
if (matid >= 3u) {
|
|
getMaterialParams(matid, matp0, matp1, matp2, matp3, matp4, matp5, matp6, matp7);
|
|
}
|
|
#ifdef _ClearCoat
|
|
vec3 coatTintCol = vec3(matp1.w, matp2.x, matp2.y);
|
|
#endif
|
|
#ifdef _Sheen
|
|
vec3 sheenTintCol = vec3(matp5.z, matp5.w, matp6.x);
|
|
#endif
|
|
#ifdef _SSS
|
|
vec3 sssColorVal = vec3(matp4.w, matp5.x, matp5.y);
|
|
vec3 sssRadiusScaled = vec3(matp4.x, matp4.y, matp4.z) * matp7.x;
|
|
#endif
|
|
#endif
|
|
|
|
vec4 g1 = textureLod(gbuffer1, texCoord, 0.0); // Basecolor.rgb, spec/occ
|
|
vec2 occspec = unpackFloat2(g1.a);
|
|
vec3 albedo = surfaceAlbedo(g1.rgb, metallic); // g1.rgb - basecolor
|
|
vec3 f0 = surfaceF0(g1.rgb, metallic);
|
|
#ifdef _ExtBRDF
|
|
f0 = mix(f0, min(g1.rgb, vec3(2.0)), vec3(matp6.y, matp6.z, matp6.w));
|
|
#endif
|
|
|
|
float depth = textureLod(gbufferD, texCoord, 0.0).r * 2.0 - 1.0;
|
|
vec3 p = getPos(eye, eyeLook, normalize(viewRay), depth, cameraProj);
|
|
vec3 v = normalize(eye - p);
|
|
float dotNV = max(dot(n, v), 0.0);
|
|
|
|
#ifdef _ClearCoat
|
|
vec4 gCoat = textureLod(gbufferCoatNormal, texCoord, 0.0);
|
|
vec3 nCoat;
|
|
nCoat.z = 1.0 - abs(gCoat.x) - abs(gCoat.y);
|
|
nCoat.xy = nCoat.z >= 0.0 ? gCoat.xy : octahedronWrap(gCoat.xy);
|
|
nCoat = normalize(nCoat);
|
|
#endif
|
|
|
|
#ifdef _Anisotropy
|
|
#ifdef _gbuffer2
|
|
vec4 g2 = textureLod(gbuffer2, texCoord, 0.0);
|
|
vec3 wTangent = decodeTangent(g2.a, n);
|
|
#else
|
|
vec3 wTangent = vec3(0.0);
|
|
#endif
|
|
#endif
|
|
|
|
#ifdef _Brdf
|
|
vec2 envBRDF = texelFetch(senvmapBrdf, ivec2(vec2(dotNV, 1.0 - roughness) * 256.0), 0).xy;
|
|
#endif
|
|
|
|
// Envmap
|
|
#ifdef _Irr
|
|
vec3 envl = shIrradiance(n, shirr);
|
|
#ifdef _EnvTex
|
|
envl /= PI;
|
|
#endif
|
|
#else
|
|
vec3 envl = vec3(1.0);
|
|
#endif
|
|
|
|
#ifdef _Rad
|
|
#ifdef _Anisotropy
|
|
vec3 reflectionWorld = anisotropicIBLDirection(n, v, wTangent,
|
|
matp0.x, roughness);
|
|
#else
|
|
vec3 reflectionWorld = reflect(-v, n);
|
|
#endif
|
|
float lod = getMipFromRoughness(roughness, envmapNumMipmaps);
|
|
vec3 prefilteredColor = textureLod(senvmapRadiance, envMapEquirect(reflectionWorld), lod).rgb;
|
|
#endif
|
|
|
|
#ifdef _EnvLDR
|
|
envl.rgb = srgbToLinear(envl.rgb);
|
|
#ifdef _Rad
|
|
prefilteredColor = srgbToLinear(prefilteredColor);
|
|
#endif
|
|
#endif
|
|
|
|
envl.rgb *= albedo;
|
|
|
|
#ifdef _Rad // Indirect specular
|
|
envl.rgb += prefilteredColor * (f0 * envBRDF.x + envBRDF.y) * 1.5 * occspec.y;
|
|
#else
|
|
#ifdef _EnvCol
|
|
envl.rgb += backgroundCol * surfaceF0(g1.rgb, metallic); // f0
|
|
#endif
|
|
#endif
|
|
|
|
#ifdef _ExtBRDF
|
|
float iblSheenWeight = 1.0;
|
|
float iblCoatWeight = 1.0;
|
|
vec3 coatTintAbsorb = vec3(1.0);
|
|
|
|
#ifdef _Sheen
|
|
float sheenAlb = sheenIBLAlbedo(matp0.z, matp0.w, dotNV);
|
|
iblSheenWeight = max(1.0 - sheenAlb *
|
|
max(max(sheenTintCol.r, sheenTintCol.g), sheenTintCol.b), 0.0);
|
|
#endif
|
|
|
|
#ifdef _ClearCoat
|
|
float dotNVCoat = max(dot(nCoat, v), 0.0);
|
|
float coatF = coatIBLFresnel(matp1.x, matp1.z, dotNVCoat);
|
|
iblCoatWeight = max(1.0 - coatF, 0.0);
|
|
if (matp1.x > 0.0) {
|
|
coatTintAbsorb = mix(vec3(1.0), clamp(coatTintCol, 0.0, 1.0),
|
|
clamp(1.0 / max(dotNVCoat, 0.3) * 0.2, 0.0, 1.0));
|
|
}
|
|
#endif
|
|
|
|
float iblLayerWeight = iblSheenWeight * iblCoatWeight;
|
|
envl.rgb *= iblLayerWeight;
|
|
|
|
brdf_sheenWeight = iblSheenWeight;
|
|
brdf_coatWeight = iblCoatWeight;
|
|
brdf_coatTintAbsorb = coatTintAbsorb;
|
|
#ifdef _Sheen
|
|
brdf_sheenAlbedo = sheenAlb;
|
|
#endif
|
|
#ifdef _ClearCoat
|
|
brdf_coatF0 = (matp1.z - 1.0) / (matp1.z + 1.0);
|
|
brdf_coatF0 = brdf_coatF0 * brdf_coatF0;
|
|
#endif
|
|
#ifdef _Transmission
|
|
brdf_transmissionF0 = (matp3.x - 1.0) / (matp3.x + 1.0);
|
|
brdf_transmissionF0 = brdf_transmissionF0 * brdf_transmissionF0;
|
|
#endif
|
|
|
|
#ifdef _Transmission
|
|
float transF = transmissionIBLFresnel(matp3.x, dotNV);
|
|
float transmittance = 1.0 - transF;
|
|
#ifdef _Rad
|
|
if (matp2.z > 0.0 && transmittance > 0.0) {
|
|
vec3 refrDir = transmissionIBLDirection(n, v, matp3.x);
|
|
float transLod = getMipFromRoughness(matp2.w, envmapNumMipmaps);
|
|
vec3 transColor = textureLod(senvmapRadiance,
|
|
envMapEquirect(refrDir), transLod).rgb;
|
|
transColor = min(transColor, vec3(20.0));
|
|
#ifdef _EnvLDR
|
|
transColor = srgbToLinear(transColor);
|
|
#endif
|
|
envl.rgb += albedo * matp2.z * transmittance * transColor * dotNV
|
|
* iblLayerWeight;
|
|
}
|
|
#endif
|
|
#endif
|
|
|
|
#ifdef _ClearCoat
|
|
envl.rgb *= coatTintAbsorb;
|
|
#ifdef _Rad
|
|
if (coatF > 0.0) {
|
|
float coatLod = getMipFromRoughness(matp1.y, envmapNumMipmaps);
|
|
vec3 coatRefl = reflect(-v, nCoat);
|
|
vec3 coatColor = textureLod(senvmapRadiance,
|
|
envMapEquirect(coatRefl), coatLod).rgb;
|
|
coatColor = min(coatColor, vec3(20.0));
|
|
#ifdef _EnvLDR
|
|
coatColor = srgbToLinear(coatColor);
|
|
#endif
|
|
envl.rgb += coatColor * coatF * iblSheenWeight;
|
|
}
|
|
#endif
|
|
#endif
|
|
|
|
#ifdef _Sheen
|
|
#ifdef _Rad
|
|
if (sheenAlb > 0.0) {
|
|
float sheenLod = getMipFromRoughness(matp0.w, envmapNumMipmaps);
|
|
vec3 sheenRefl = reflect(-v, n);
|
|
vec3 sheenColor = textureLod(senvmapRadiance,
|
|
envMapEquirect(sheenRefl), sheenLod).rgb;
|
|
sheenColor = min(sheenColor, vec3(20.0));
|
|
#ifdef _EnvLDR
|
|
sheenColor = srgbToLinear(sheenColor);
|
|
#endif
|
|
envl.rgb += sheenColor * sheenTintCol * sheenAlb;
|
|
}
|
|
#endif
|
|
#endif
|
|
#endif // _ExtBRDF
|
|
|
|
envl.rgb *= envmapStrength * occspec.x;
|
|
fragColor.rgb = envl;
|
|
|
|
#ifdef _Sun
|
|
vec3 sh = normalize(v + sunDir);
|
|
float sdotNH = max(0.0, dot(n, sh));
|
|
float sdotVH = max(0.0, dot(v, sh));
|
|
float sdotNL = max(0.0, dot(n, sunDir));
|
|
float svisibility = 1.0;
|
|
#ifdef _Anisotropy
|
|
vec3 sdirect;
|
|
if (abs(matp0.x) > 0.001 && dot(wTangent, wTangent) > 0.001) {
|
|
vec3 sbitangent = normalize(cross(n, wTangent));
|
|
sdirect = lambertDiffuseBRDF(albedo, sdotNL) +
|
|
anisotropicBRDF(f0, roughness, matp0.x, matp0.y,
|
|
wTangent, sbitangent, n, sunDir, v, sdotNL, dotNV) * occspec.y;
|
|
} else {
|
|
sdirect = lambertDiffuseBRDF(albedo, sdotNL) +
|
|
specularBRDF(f0, roughness, sdotNL, sdotNH, dotNV, sdotVH) * occspec.y;
|
|
}
|
|
#else
|
|
vec3 sdirect = lambertDiffuseBRDF(albedo, sdotNL) +
|
|
specularBRDF(f0, roughness, sdotNL, sdotNH, dotNV, sdotVH) * occspec.y;
|
|
#endif
|
|
|
|
float sunSheenWeight = brdf_sheenWeight;
|
|
float sunCoatWeight = brdf_coatWeight;
|
|
|
|
#ifdef _Sheen
|
|
vec3 sunSheen = sheenBRDF(matp0.z, matp0.w, sheenTintCol, sdotNL, sdotNH, dotNV);
|
|
#endif
|
|
|
|
#ifdef _ClearCoat
|
|
vec3 sunCoat = clearcoatBRDF(matp1.x, matp1.y, matp1.z, nCoat, sunDir, v, sh);
|
|
#endif
|
|
|
|
float sunLayerWeight = sunSheenWeight * sunCoatWeight;
|
|
sdirect *= sunLayerWeight;
|
|
#ifdef _Transmission
|
|
sdirect += transmissionBRDF(albedo, matp2.z, matp2.w, matp3.x, matp3.y, sdotNL, dotNV, sdotVH) * sunLayerWeight;
|
|
#endif
|
|
#ifdef _ClearCoat
|
|
sdirect *= brdf_coatTintAbsorb;
|
|
sdirect += sunCoat * sunSheenWeight;
|
|
#endif
|
|
#ifdef _Sheen
|
|
sdirect += sunSheen;
|
|
#endif
|
|
|
|
#ifdef _ShadowMap
|
|
#ifdef _ShadowMapAtlas
|
|
tileBounds = tileBoundsSunArray[0];
|
|
#endif
|
|
#ifdef _CSM
|
|
svisibility = shadowTestCascade(
|
|
#ifdef _ShadowMapAtlas
|
|
#ifndef _SingleAtlas
|
|
shadowMapAtlasSun
|
|
#else
|
|
shadowMapAtlas
|
|
#endif
|
|
#else
|
|
shadowMap
|
|
#endif
|
|
, eye, p + n * shadowsBias * 10, shadowsBias
|
|
);
|
|
#else
|
|
vec4 lPos = LWVP * vec4(p + n * shadowsBias * 100, 1.0);
|
|
if (lPos.w > 0.0) svisibility = shadowTest(
|
|
#ifdef _ShadowMapAtlas
|
|
#ifndef _SingleAtlas
|
|
shadowMapAtlasSun
|
|
#else
|
|
shadowMapAtlas
|
|
#endif
|
|
#else
|
|
shadowMap
|
|
#endif
|
|
, lPos.xyz / lPos.w, shadowsBias
|
|
);
|
|
#endif
|
|
#endif
|
|
|
|
fragColor.rgb += sdirect * svisibility * sunCol;
|
|
#endif
|
|
|
|
#ifdef _SinglePoint
|
|
fragColor.rgb += sampleLight(
|
|
p, n, v, dotNV, pointPos, pointCol, albedo, roughness, occspec.y, f0
|
|
#ifdef _ShadowMap
|
|
, 0, pointBias, true
|
|
#endif
|
|
#ifdef _Spot
|
|
, true, spotData.x, spotData.y, spotDir, spotData.zw, spotRight // TODO: Test!
|
|
#endif
|
|
#ifdef _ClearCoat
|
|
, matp1.x, matp1.y, matp1.z, coatTintCol, nCoat
|
|
#endif
|
|
#ifdef _Sheen
|
|
, matp0.z, matp0.w, sheenTintCol
|
|
#endif
|
|
#ifdef _Anisotropy
|
|
, matp0.x, matp0.y, wTangent
|
|
#endif
|
|
#ifdef _SSS
|
|
, matp3.z, sssColorVal, sssRadiusScaled, matp3.w
|
|
#endif
|
|
#ifdef _Transmission
|
|
, matp2.z, matp2.w, matp3.x, matp3.y
|
|
#endif
|
|
);
|
|
#endif
|
|
|
|
#ifdef _Clusters
|
|
float viewz = linearize(depth * 0.5 + 0.5, cameraProj);
|
|
int clusterI = getClusterI(texCoord, viewz, cameraPlane);
|
|
int numLights = int(texelFetch(clustersData, ivec2(clusterI, 0), 0).r * 255);
|
|
|
|
#ifdef HLSL
|
|
viewz += textureLod(clustersData, vec2(0.0), 0.0).r * 1e-9; // TODO: krafix bug, needs to generate sampler
|
|
#endif
|
|
|
|
#ifdef _Spot
|
|
int numSpots = int(texelFetch(clustersData, ivec2(clusterI, 1 + maxLightsCluster), 0).r * 255);
|
|
int numPoints = numLights - numSpots;
|
|
#endif
|
|
|
|
for (int i = 0; i < min(numLights, maxLightsCluster); i++) {
|
|
int li = int(texelFetch(clustersData, ivec2(clusterI, i + 1), 0).r * 255);
|
|
fragColor.rgb += sampleLight(
|
|
p,
|
|
n,
|
|
v,
|
|
dotNV,
|
|
lightsArray[li * 3].xyz, // lp
|
|
lightsArray[li * 3 + 1].xyz, // lightCol
|
|
albedo,
|
|
roughness,
|
|
occspec.y,
|
|
f0
|
|
#ifdef _ShadowMap
|
|
// light index, shadow bias, cast_shadows
|
|
, li, lightsArray[li * 3 + 2].x, lightsArray[li * 3 + 2].z != 0.0
|
|
#endif
|
|
#ifdef _Spot
|
|
, lightsArray[li * 3 + 2].y != 0.0
|
|
, lightsArray[li * 3 + 2].y // spot size (cutoff)
|
|
, lightsArraySpot[li].w // spot blend (exponent)
|
|
, lightsArraySpot[li].xyz // spotDir
|
|
, vec2(lightsArray[li * 3].w, lightsArray[li * 3 + 1].w) // scale
|
|
, lightsArraySpot[li * 2 + 1].xyz // right
|
|
#endif
|
|
#ifdef _ClearCoat
|
|
, matp1.x, matp1.y, matp1.z, coatTintCol, nCoat
|
|
#endif
|
|
#ifdef _Sheen
|
|
, matp0.z, matp0.w, sheenTintCol
|
|
#endif
|
|
#ifdef _Anisotropy
|
|
, matp0.x, matp0.y, wTangent
|
|
#endif
|
|
#ifdef _SSS
|
|
, matp3.z, sssColorVal, sssRadiusScaled, matp3.w
|
|
#endif
|
|
#ifdef _Transmission
|
|
, matp2.z, matp2.w, matp3.x, matp3.y
|
|
#endif
|
|
);
|
|
}
|
|
#endif // _Clusters
|
|
|
|
fragColor.rgb = clamp(fragColor.rgb, vec3(0.0), vec3(65504.0));
|
|
if (any(isnan(fragColor.rgb)) || any(isinf(fragColor.rgb))) {
|
|
fragColor.rgb = vec3(0.0);
|
|
}
|
|
|
|
fragColor.a = 1.0; // Mark as opaque
|
|
}
|